gram: nux

> ./cell/par/index.nix

{ home-manager, nixos-hardware, pkgs, pool, ... }@sources:
{
  specialArgs = sources // { name = "nixos"; machine = "par"; };
  modules = [
    "${nixos-hardware}/framework/13-inch/11th-gen-intel/default.nix"
    home-manager.nixosModules.default

    (import ../../module/login.nix {
      user = "nixos";
      command = ''nu -e "hop home"'';
    })

    ./signal.nix
    ./machine.nix
    ./process.nix

    ((pool.outputs.current sources.arch).channel "enp0s13f0u1")
    ../../mach/base.nix

    ({ users.users.root.openssh.authorizedKeys.keys = [
      "ssh-ed25519 AAAAC3NzaC1lZDI1NTE5AAAAIH31k4XJU6NYkDWKbsfQcHraO1b2rBX7jX3xSOtyLCK0 calliope@chesapeake"
    ]; })
    (import ../../module/user.nix { super = true; })
    ({ home-manager.backupFileExtension = ".home.backup"; })

    ../../module/incus.nix
    ../../module/lobby.nix

    ../../module/essence.nix
    ../../module/psql.nix
    ../../module/relay.nix
    ../../module/zfs.nix

    ( import ../../module/process.nix rec {
      user = "nixos";
      name = "share"; channel = 2222;
      pkg = pkgs.writeShellScriptBin name ''
      ${pkgs.miniserve}/bin/miniserve -p ${toString channel} -H /home/${user}/share -z -g
    ''; })

    ( import ../../module/process.nix rec {
      user = "nixos";
      name = "page"; channel = 2223;
      pkg = pkgs.writeShellScriptBin name ''
      ${pkgs.miniserve}/bin/miniserve -p ${toString channel} -H /home/${user}/unshare/page/confer -z -g
    ''; })

    ( import ../../module/mesh.nix {
      machine = "baseboard";
      mesh = "mesh";
      beacons = [ "10.0.10.100" "10.0.10.101" ];
      map = {
        "10.0.10.100" = [ "173.66.32.84:4242" ];
        "10.0.10.101" = [ "173.66.32.84:4243" ];
      };
    })
  ];
}